Microsoft Dynamic AX 2009 : Syntax (part 2) - Statements - Data-Aware Statements

Statements

X++ statements specify object state and object behavior. Table 3 provides examples of X++ language statements that are commonly found in many programming languages.

int i = 42;
;
i = 1;
i++;
++i;
i--;
--i;
i += 1;
i -= 1;

int i;
{
    i = 3;
    i++;
}

int i = 42;
;
print i;
print "Hello World";
print 5.2;
pause;

boolean b = true;
int i = 42;
;
if ( b == true )
{
    i++;
}
else
{
    i--;
}

int i;
;
for ( i = 0; i < 100; i++ )
{
    if ( i > 50 )
    {
        break;
    }
}

int i;
int j = 0;
;
for( i = 0; i < 100; i++ )
{
    if ( i < 50 )
    {
        continue;
    }
    j++;
}

int i = 4;
;
while ( i <= 100 )
{
    i++;
}

int i = 4;
;
do
{
    i++;
}
while ( i <= 100 );

int i;
;
for ( i = 0; i < 42; i++ )
{
    print i;
    pause;
}

str s = "test";
;
switch ( s )
{
    case "test" :
        print s;
        break;
    default :
        print "fail";
}
pause;

print "Hello World";
pause;

window 100, 10 at 100,10;
print "Hello World";
pause;

breakpoint; //Causes the debugger to be invoked

int foo()
{
    return 42;
}

throw error("Error text");

try
{
    throw error("Force exception");
}
catch( exception::Error )
{
    print "Error";
    pause;
}
catch
{
    print "Another exception";
    pause;
}

try
{
    throw error("Force exception");
}
catch( exception::Error )
{
    retry;
}

System.Text.StringBuilder sb;
sb = new System.Text.StringBuilder();
sb.Append("Hello World");
print sb.ToString();
pause;

static void myJob(Args _args)
{
     str myLocalFunction()
     {
        return "Hello World";
     }
     ;
     print myLocalFunction();
     pause;
}

guid g = newguid();
;
print abs(-1);

MyTable myTable;
;
flush myTable;

MyTable myTable;
;
while select myTable
{
    print myTable.myField;
}
changecompany("ZZZ")
{
   while select myTable
   {
       print myTable.myField;
   }
}
pause;

Data-Aware Statements

The X++ language has built-in support for querying and manipulating database data. The syntax for database statements is similar to Structured Query Language (SQL), and this section assumes that you’re familiar with SQL. The following code shows how a select statement is used to return only the first selected record from the MyTable database table and how the data in the record’s myField field is printed.

static void myJob(Args _args)
{
     MyTable myTable;
     ;
     select firstOnly * from myTable where myTable.myField1=='value';
     print myTable.myField2;
     pause;
}

The “* from” part of the select statement in the example is optional. You can replace the asterisk (*) character with a comma-separated field list, such as myField2, myField3. You must define all fields, however, on the selection table model element, and only one selection table is allowed immediately after the from keyword. The where expression in the select statement can comprise any number of logical and relational operators. The firstOnly keyword is optional and can be replaced by one or more of the optional keywords. Table 4 describes all the possible keywords.

while select crosscompany:companies myTable { }

The following code example demonstrates how a table index clause is used to suggest the index that a database server should use when querying tables. The Dynamics AX runtime appends an order by clause and the index fields to the first select statement’s database query. Records are thus ordered by the index. The Dynamics AX runtime can insert a query hint into the second select statement’s database query, if the hint is reasonable to use.

static void myJob(Args _args)
{
    MyTable1 myTable1;
    MyTable2 myTable2;
    ;
    while select myTable1
        index myIndex1
    {
        print myTable1.myField2;
    }

    while select myTable2
        index hint myIndex2
    {
        print myTable2.myField2;
    }
    pause;
}

The following code example demonstrates how the results from a select query can be ordered and grouped. The first select statement specifies that the resulting records must be sorted in ascending order based on myField1 values and then descending order based on myField2 values. The second select statement specifies that the resulting records must be grouped by myField1 values and sorted in descending order.

static void myJob(Args _args)
{
    MyTable myTable;
    ;
    while select myTable
        order by Field1 asc, Field2 desc
    {
        print myTable.myField;
    }
    while select myTable
        group by Field1 desc
    {
        print myTable.Field1;
    }
    pause;
}

The following code demonstrates use of the avg and count aggregate functions in select statements. The first select statement averages the values in the myFieldmyField field. The second select statement counts the number of records the selection returns and assigns the result to the myField column and assigns the result to the field.

static void myJob(Args _args)
{
     MyTable myTable;
     ;
     select avg(myField) from myTable;
     print myTable.myField;

     select count(myField) from myTable;
     print myTable.myField;
     pause;
}

Table 5 describes the aggregate functions supported in X++ select statements.

The following code example demonstrates how tables are joined with join conditions. The first select statement joins two tables by using an equality join condition between fields in the tables. The second select statement joins three tables to illustrate how you can nest join conditions and use an exists operator as an existence test with a join condition. The second select statement also demonstrates how you can use a group by sort in join conditions. In fact, the join condition can comprise multiple nested join conditions because the syntax of the join condition is the same as the body of a select statement.

static void myJob(Args _args)
{
     MyTable1 myTable1;
     MyTable2 myTable2;
     MyTable3 myTable3;
     ;
     select myField from myTable1
        join myTable2
           where myTable1.myField1=myTable2.myField1;
     print myTable1.myField;

     select myField from myTable1
        join myTable2
          group by myTable2.myField1
          where myTable1.myField1=myTable2.myField1;
             exists join myTable3
                where myTable1.myField1=myTable3.mField2;
     print myTable1.myField;
     pause;
}

Table 6 describes the exists operator and the other join operators that can be used in place of the exists operator in the preceding example.

The following example demonstrates use of the while select statement that increments the myTable variable’s record cursor on each loop.

static void myJob(Args _args)
{
     MyTable myTable;
     ;
     while select myTable
     {
         Print myTable.myField;
     }
}

You must use the ttsbegin, ttscommit, and ttsabort transaction statements to modify records in tables and to insert records into tables. The ttsbegin statement marks the beginning of a database transaction block; ttsbegin-ttscommit transaction blocks can be nested. The ttsbegin statements increment the transaction level; the ttscommit statements decrement the transaction level. The outermost block decrements the transaction level to zero and commits all database inserts and updates performed since the first ttsbegin statement to the database. The ttsabort statement rolls back all the database inserts, updates, and deletions performed since the ttsbegin statement. Table 7 provides examples of these transaction statements for single records and operations and for set-based (multiple-record) operations.

boolean b = true;
;
ttsbegin;
if ( b == true )
    ttscommit;
else
    ttsabort;

MyTable myTable;
;
ttsbegin;
select forupdate myTable;
myTable.myField = "new value";
myTable.update();
ttscommit;

MyTable myTable;
;
ttsbegin;
myTable.id = "new id";
myTable.myField = "new value";
myTable.insert();
ttscommit;

MyTable myTable;Int64 numberOfRecordsAffected;
; ttsbegin;

update_recordset myTable setting
    myField1 = "value1",
    myField2 = "value2"
    where myTable.id == "001";
numberOfRecordsAffected = myTable.RowCount();
ttscommit;

MyTable1 myTable1;
MyTable2 myTable2;
Int64 numberOfRecordsAffected;
;
ttsbegin;
insert_recordset myTable2 ( myField1, myField2 )
    select myField1, myField2 from myTable1;
numberOfRecordsAffected = myTable.RowCount();
ttscommit;

MyTable myTable;
Int64 numberOfRecordsAffected;
;
ttsbegin;
delete_from myTable
    where myTable.id == "001";
numberOfRecordsAffected = myTable.RowCount();
ttscommit;

The last example in Table 7 demonstrates the method RowCount, which is new in Dynamics AX 2009. Its purpose is to get the count of records that are affected by set-based operations, namely, insert_recordset, update_recordset, and delete_from.